在Excel公式中，有些函數是獨行俠，而有些函數經常是成對出現的，今天蘭色就帶大家一起盤點Excel表格中八大經典函數組合。

1、 IF  +  And

作用：并列多條件判斷

【例】如下圖所示，在C列設置公式，如果A列值 小于500 且B列值為 未到期 ，則返回”補款“，否則顯示為空。

公式：C2

= IF ( AND (A2<500,B2="未到期"),"補款","")

說明：兩個條件同時成立用AND,任一個成立用OR函數。

2、 Index  +  Match

作用：根據條件查詢

【例2】如下圖所示，要求根據月份和費用項目，查找金額

E10公式：

= INDEX ( B2:G6, MATCH (B10,$A$2:$A$6,0), MATCH (A10,$B$1:$G$1,0) )

公式說明：

先用MATCH函數查找3月在第一行中的位置

= MATCH (B10,$A$2:$A$6,0)

再用MATCH函數查找費用項目在A列的位置

= MATCH (A10,$B$1:$G$1,0)

最后用INDEX根據行數和列數提取數值

= INDEX(區(qū)域,行數,列數）

3、 Iferror  +  Vlookup

作用：當Vlookup查找不到時屏蔽查錯誤值

【例】如下圖所示，要求根據產品名稱在上表中查找單價，如果產品不存在則顯示為空白

B9公式：

= IFERROR ( VLOOKUP (A8,$A$1:$D$5,3,0) , "" )

4、 Mid  +  Find

作用：根據條件截取字符串

【例】在個人信里截取出年齡

B2公式

= MID (A2, FIND (" ",A2)+1,9)

注：find查找分隔符的位置，MID負責截取字符

5、 Left  +  lenB  +  Len

作用：分離漢字、數字和字母

示例：

= LEFT (A2, LENB (A2)- LEN (A2))

注：帶B的函數是按字節(jié)計數，而一個漢字占2個字節(jié)，數字和字母則占1個。所以用 LENB(A2)-LEN(A2)可以倒推出漢字的個數，然后用left或mid函數截取。

6、 index  +  Small  +  Row

作用：一對多查找

【例】如下圖所示，要求在F列查找“張明城”的個人消費記錄 

F2公式

{= INDEX (C:C, SMALL (IF(B$2:B$10=F$1, ROW ($2:$10)),ROW(A1)))}

公式解析：

• IF(B$2:B$10=F$1,ROW($2:$10)) ： 如果B列的姓名和F1的姓名相同，就返回它的行號。不相同的返回FALSE

•  Row(a1) ：是返回A1的行號1，如果向下復制會變?yōu)?Row(a2)，返回2，其實用它的目的是當公式向下復制時可以生成序號：1，2，3...然后取符合條件的第1個行號，第2個行號...

• SMALL() : 從符合條件的行號中從小到大，逐個提取符合條件的行

• INDEX()  :根據取得的行號從C列提取值

• { } ：數組公式（含有逐一運算的公式）需要按ctrl+shift+enter 輸入大括號（一定要是自動生成的，不能手輸入大括號）。

7、 Sum   +  Offset  +  Count

作用：最后N天求和

【例】在D2單元格返回B列最近7天的銷量

D2公式：

= SUM ( OFFSET (B1, COUNTA(B:B) -7,0,7,1))

注：Counta負責統(tǒng)計B列非空值個數，offset負責生成動態(tài)最后N天區(qū)域，SUM負責求和

8、 Sumproduct  +  Countif

作用：計算不重復值個數

【例】：統(tǒng)計B列的客戶數量

= SUMPRODUCT (1/ COUNTIF (B2:B19,B2:B19))

注：Countif函數統(tǒng)計出每個客戶的出現次數，Sumprodcut對 1/出現次數 進行求和。每個客戶無論出現多少次，求和的結果都是1，求和后正好是不重復個數。

蘭色說 ：Excel公式中的函數嵌套對新手是一個難點，所以掌握這些固定套路尤為重要。

長按 下面二維碼圖片，點上面 ” 前往圖中包含的公眾號 “ 然后再點關注，每天可以收到一篇蘭色最新寫的excel教程。

工作中最常用的Excel函數公式，全印在一張超大的 鼠標墊 上( 送40集配套視頻 )， 點我查看詳情